home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs38.d81
/
laser20.arc
/
CAJUN 1541
(
.txt
)
next >
Wrap
Commodore BASIC
|
2009-10-10
|
3KB
|
114 lines
1 REM *********************************
2 REM * CAJUN RELISH 1541 NOV 86 *
3 REM *********************************
4 REM * WILL CORLEY *
5 REM * 7551 TWILIGHT DR. *
6 REM * SACRAMENTO, CA *
7 REM * 95822 *
8 REM *********************************
9 DIM P(6,120),Q(6,120)
10 TEM=49194:X=TEM:J=49666
11 READ A:IF A<>999 THEN POKE X,A:X=X+1:GOTO 11
12 K$=CHR$(0):F=512
13 FOR X=1 TO 254:NU$=NU$+K$:NEXT
14 POKE 53280,11:POKE 53281,12
15 PRINT "[147]":PRINT TAB(12)"CAJUN RELISH 1541"
16 PRINT TAB(12)"[151][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183]"
17 PRINT TAB(8)"(C) 1986 BY WILL CORLEY"
18 POKE 198,0
19 INPUT "SOURCE DRIVE 8[157][157][157]";SD
20 INPUT "DESTINATION DRIVE 9[157][157][157]";DD
21 IF SD<8 OR SD>11 OR DD<8 OR DD>11 OR SD=DD THEN 15
22 INPUT "RELATIVE FILE TO COPY";N$:IF N$="" THEN 15
23 CLOSE 2:CLOSE 15:OPEN 15,SD,15,"I":GOSUB 102:OPEN 2,SD,2,"#":GOSUB 102
24 T=18:S=1:CC=194
25 GOSUB 95:X=0
26 N=X*32:C=PEEK(J+N)
27 IF C<>132 THEN 31
28 GOSUB 98:IF F$<>N$ THEN 31
29 FT=PEEK(J+1+N):FS=PEEK(J+2+N):B=PEEK(J+29+N)*256+PEEK(J+28+N)
30 L=PEEK(J+21+N):CLOSE 2:CLOSE 15:GOTO 34
31 X=X+1:IF X<8 THEN GOTO 26
32 IF T<>0 THEN 25
33 RUN
34 OPEN 14,DD,15,"U;":PRINT#14,"I"
35 INPUT#14,E,E$,ET,ES:IF E>19 THEN 104
36 OPEN 3,DD,3,N$+",S,W"
37 INPUT#14,E,E$,ET,ES:IF E>19 THEN 104
38 OPEN 15,SD,15
39 OPEN 2,SD,2,"#"
40 PRINT "[147][151]";
41 PRINT TAB(16)" "
42 SS=-1*INT(B/-121)
43 FOR X=1 TO SS:PRINT#3,NU$;
44 GOSUB 107:PRINT#14,"M-R" H$ K$ CHR$(2)
45 GET#14,A$:TS(X)=PEEK(F)
46 GET#14,A$:SS(X)=PEEK(F)
47 NEXT X
48 T=FT:S=FS:U=1:V=1:CC=4
49 GOSUB 95
50 Y=254:IF PEEK(1024)=0 THEN Y=PEEK(1025)
51 POKE 251,Y:POKE 253,2:POKE 254,4:SYSTEM
52 GOSUB 107:PRINT#14,"M-R" H$ K$ CHR$(2)
53 GET#14,A$:P(V,U)=PEEK(F)
54 GET#14,A$:Q(V,U)=PEEK(F)
55 U=U+1:IF U>120 THEN V=V+1:U=1
56 IF T<>0 THEN 49
57 GOSUB 102:CLOSE 2:CLOSE 3:CLOSE 14:CLOSE 15
58 PRINT "DATA TRANSFERED"
59 OPEN 15,DD,15:OPEN 2,DD,2,"#"
60 T=18:S=1:CC=194
61 GOSUB 95:X=0
62 N=X*32:C=PEEK(J+N)
63 IF C<>129 THEN 69
64 GOSUB 98:IF F$<>N$ THEN 69
65 PRINT#15,"B-P";2;N+2
66 PRINT#2,CHR$(132);CHR$(P(1,1));CHR$(Q(1,1));
67 PRINT#15,"B-P";2;N+21:PRINT#2,CHR$(TS(1));CHR$(SS(1));CHR$(L);
68 PRINT#15,"U2";2;0;T1;S1:GOSUB 102:GOTO 72
69 X=X+1:IF X<8 THEN 62
70 IF T<>0 THEN 61
71 RUN
72 PRINT "CREATING SIDE SECTORS"
73 Z$="":U=U-1:IF U=0 THEN U=120
74 FOR X=1 TO 6:Z$=Z$+CHR$(TS(X))+CHR$(SS(X)):NEXT X
75 FOR X=1 TO SS
76 A$=CHR$(X-1)+CHR$(L)+Z$
77 FOR XZ=1 TO 120:A$=A$+CHR$(P(X,XZ))+CHR$(Q(X,XZ)):NEXT XZ
78 PRINT#15,"U1";2;0;TS(X);SS(X):GOSUB 102
79 P=2:IF X=SS THEN A$=CHR$(U*2+15)+A$:P=0
80 PRINT#15,"B-P";2;P:IF P=0 THEN PRINT#2,K$;
81 PRINT#2,A$;
82 PRINT#15,"U2";2;0;TS(X);SS(X):GOSUB 102
83 NEXT X
84 CLOSE 2:CLOSE 15
85 PRINT "[147]"
86 PRINT " CAJUN RELISH HAS BEEN RELEASED TO THEPUBLIC DOMAIN AS FREEWARE.";
87 PRINT " A DONATION OF$1,5 OR $10 WOULD GLADLY BE ACCEPTED!"
88 PRINT " SUPPORT THE FREEWARE CONCEPT!"
89 PRINT TAB(14)"WILL CORLEY"
90 PRINT TAB(11)"7551 TWILIGHT DR."
91 PRINT TAB(13)"SACRAMENTO,CA"
92 PRINT TAB(17)"95822"
93 TI$="000000":WAIT 161,1:RUN
94 END
95 PRINT#15,"U1";2;0;T;S:GOSUB 102:PRINT#15,"B-P";2;0
96 POKE 251,0:POKE 252,CC:SYSTEM+26
97 T1=T:S1=S:T=PEEK(CC*256):S=PEEK(CC*256+1):RETURN
98 F$="":FOR Y=J+3+N TO J+18+N
99 A$=CHR$(PEEK(Y)):IF PEEK(Y)=160 THEN 101
100 F$=F$+A$
101 NEXT Y:RETURN
102 INPUT#15,E,E$,ET,ES:IF E>19 THEN 104
103 RETURN
104 CLOSE 2:CLOSE 3:CLOSE 14:CLOSE 15
105 PRINT "DISK ERROR":PRINT E;E$;ET;ES
106 TI$="000000":WAIT 161,1:RUN
107 IF H$=CHR$(8) THEN H$=CHR$(10):RETURN
108 H$=CHR$(8):RETURN
109 DATA 162,3,32,201,255,160,0,177,253,32
110 DATA 210,255,200,196,251,208,246,32,204,255
111 DATA 96,234,234,234,234,234,162,2,32,198
112 DATA 255,160,0,32,228,255,145,251,32,183
113 DATA 255,208,3,200,208,243,32,204,255,96,999